Page 1 of 1

How to combine (join/merge) multiple .efu file lists?

Posted: Fri Dec 28, 2018 8:28 pm
by SuperDude
I would like to create individual .efu file lists for cataloging CDs and DVDs, then combine all of the individual .efu file lists into a single .efu “master” file, so I can open the “master” .efu file and search through all of the CDs and DVDs at once. How would I go about doing this, please? Thank you!

Re: How to combine (join/merge) multiple .efu file lists?

Posted: Fri Dec 28, 2018 9:10 pm
by vanisk
EFU files are comma-separated values (CSV) files which can be opened in text editors (Can also be opened in Spreadsheet).
We can just open the first file, append the contents of other efu files and store it in a single EFU file.

(or)
Place all the EFU files in a single folder, Within Command Prompt (cmd), CD to the efu file list location and run

Code: Select all

Copy *.efu final.efu

Re: How to combine (join/merge) multiple .efu file lists?

Posted: Fri Dec 28, 2018 10:29 pm
by SuperDude
@vanisk: Thank you!

Re: How to combine (join/merge) multiple .efu file lists?

Posted: Tue Jan 01, 2019 8:45 pm
by NotNull
SuperDude wrote: Fri Dec 28, 2018 8:28 pm “master” .efu file
Is @vanisk's solution good enough for you?
( I might have an alternative, but that requires writing some code and if you don't need it, that would be futile )

Re: How to combine (join/merge) multiple .efu file lists?

Posted: Wed Jan 02, 2019 2:33 pm
by NotNull
Well, I wrote it anyway ;) as I realized that it would take me more time to descrie it than to build it ..

If you want to try this:
  • Put your .EFU files together in a folder
  • Add MasterEFU.cmd to this folder
  • Change the path to your Everything.exe in the script
    (currently: c:\program files\everything\everything.exe)
  • Run MasterEFU.cmd (for example by double-clicking it in File Explorer
Using some dummy data, this results in:
2019-01-02 15_15_54-Everything (MasterEFU).png
2019-01-02 15_15_54-Everything (MasterEFU).png (110.04 KiB) Viewed 7489 times
Now you can tell on which disk the file is that you were looking for...


Notes
- Everytime the script starts, it will load all .EFU files in it's folder. So you can add/remove EFU's and those will be loaded the next time you start MasterEFU.
- If you still want your combined list, you can do a Menu:File > Export > Save as EFU


MasterEFU.cmd

Code: Select all

@echo off
setlocal ENABLEDELAYEDEXPANSION

chcp 65001

::_______________________________________________
::
::	SETTINGS
::_______________________________________________
::

	set EXE=c:\program files\everything\everything.exe
	rem set EFUPATH=c:\tools\everything\_park
	set EFUPATH=.



::_______________________________________________
::
::	INIT
::_______________________________________________
::

	pushd "%~dp0"
	set INI=%~n0.ini

	
::_______________________________________________
::
::	ACTION!
::_______________________________________________
::
	
	if not exist "%INI%" call :NEWINI

:: PREPARE INI
	set LIST=
	for %%x in (%EFUPATH%\*.efu) Do set LIST=!LIST!,"%%~fx"
	set LIST=%LIST:\=\\%
	echo filelists=%LIST%
	echo filelists=%LIST%>> "%INI%"

:: Start Everything
	start "" "%EXE%" -nodb -instance MasterEFU -config "%INI%"
   

goto :EOF



:NEWINI
(
	echo [Everything]
	echo allow_http_server=0
	echo allow_etp_server=0

	echo run_as_admin=0
	echo run_in_background=0
	echo show_in_taskbar=1
	echo show_tray_icon=0
	echo minimize_to_tray=0
	echo hide_on_close=0

	echo check_for_updates_on_startup=0

	echo auto_include_fixed_volumes=0
	echo auto_include_removable_volumes=0
	echo auto_include_fixed_refs_volumes=1
	echo auto_include_removable_refs_volumes=0

	echo file_list_filename_column_visible=1
) > "%INI%"

goto :EOF


Re: How to combine (join/merge) multiple .efu file lists?

Posted: Wed Jan 02, 2019 4:03 pm
by SuperDude
Thank you very much!

Re: How to combine (join/merge) multiple .efu file lists?

Posted: Wed Jan 02, 2019 9:18 pm
by NotNull
You're welcome! :)

Re: How to combine (join/merge) multiple .efu file lists?

Posted: Sat Mar 18, 2023 12:15 am
by DavidGDFC
Hi! I've tried this and, at first, there were no files displayed. Then I realized there was a problem with an extended character in the file path (the first letter of the word ÍNDICE):

What I've done to fix this is to replace this path:

C:\David\[[OTROS]\[ÍNDICES]

with this one:

C:\David\[[OTROS]\[INDICES]

If I don't use the script and I simply add manually my EFU files in Options > File Lists, Everything doesn't seem to have a problem with the extended character.

Is there something I can do, so I don't have to change the folder name? Thanks!

Note: I've dragged here my screenshot to illustrate my problem, but it's not displayed in the preview and I don't know how to move it from the bottom of my reply.

Re: How to combine (join/merge) multiple .efu file lists?

Posted: Sat Mar 18, 2023 12:32 am
by DavidGDFC
Edit 1: the problem with extended characters also concerns the file names of the EFU files.

Edit 2: Tested in both Everything 1.4.1.1022 and Everything 1.5.0.1340a.

Re: How to combine (join/merge) multiple .efu file lists?

Posted: Sat Mar 18, 2023 7:18 am
by horst.epp
I guess your file lists are not in UTF8
or the code page is not changed in a batch file.

Re: How to combine (join/merge) multiple .efu file lists?

Posted: Sat Mar 18, 2023 9:12 am
by NotNull
The latter ...
I updated the original code of MasterEFU.cmd.

Thanks for reporting.

Re: How to combine (join/merge) multiple .efu file lists?

Posted: Sat Mar 18, 2023 8:06 pm
by DavidGDFC
NotNull wrote: Sat Mar 18, 2023 9:12 am The latter ...
I updated the original code of MasterEFU.cmd.

Thanks for reporting.
Working great now! Thanks!